/*
	Linker script for DSE XH1151 Router (W90N740 + 4MB SDRAM + 1MB flash)

	This script is intended for C programs that will be loaded with
	the flash-based W90N740 Bootloader (copied to 0x8000, in SDRAM).
	All segments are emitted to the SDRAM block at 0x00000000, but the
	first 0x8000 is not used.

	Hugo Vincent (hugo@bluewatersys.com), Nov-2004
*/

/*
	For standardization, the entry-point is called "vectors", although
	for these programs, this is not actually the interrupt vector table.
*/

ENTRY(vectors)

SEARCH_DIR(.)

MEMORY
{
	sdram (rwx) : org = 0x00008000, len = 0x00400000	/* 4 meg of SDRAM */
}

SECTIONS
{
	.text : 
	{
        *(.text);
        . = ALIGN(4);
		*(.glue_7t);
		. = ALIGN(4);
		*(.glue_7);
		. = ALIGN(4);
        etext  =  .;
	} > sdram

	.data ADDR(.text) + SIZEOF(.text) :
	{
		datastart = .;
		__data_start__ = . ;
		*(.data)
        . = ALIGN(4);
        __data_end__ = . ;
        edata  =  .;
        _edata  =  .;
	}

	.bss ADDR(.data) + SIZEOF(.data) :
	{
		__bss_start__ = . ;
		*(.bss); *(COMMON)
		__bss_end__ = . ;
		_stack_bottom = . ;
		. += 0x8000 ;				/* reserve 64 KB for stack */
		_stack_top = . ;
	}

	end = .;
	_end = .;
	__end__ = .;

	/* Symbols */
	.stab 0 (NOLOAD) : 
	{
		[ .stab ]
	}

	.stabstr 0 (NOLOAD) :
	{
		[ .stabstr ]
	}
}